// ****************************************************************************
//
// Logic 52: Inside the Gates to the Castle
//
// ****************************************************************************

#include "defines.txt"

if (new_room) {
  load.pic(room_no);
  draw.pic(room_no);
  discard.pic(room_no);
  set.horizon(1);

  animate.obj(o1); //switch
  load.view(handle);
  set.view(o1,handle);
  position(o1,120,43);
  stop.cycling(o1);
  ignore.objs(o1);
  if (bridge_switch) {
      set.cel(o1,0);
      }
  else {
      set.cel(o1,1);
      }
  draw (o1);

  animate.obj(o2);  //vase
  load.view(112);
  set.view(o2,112);
  position(o2,100,43);
  draw(o2);

// Check what room the player came from and position them on the
// screen accordingly here, e.g:
/* if (prev_room_no == 44) {
     position(ego,44,72);
     ego_dir = 5;
 }*/

  load.view(1);
  load.view(2);
  if (is_zombie) {
     load.view(103);
     load.view(129);
     }

  load.sound(22);
  sound(22, sound_flag);

  draw(ego);
  show.pic();
}

distance(ego,o1,universe);

if (said("look")) {
  print("You are inside the gate to the castle.");
}

if ((said("look","ladder") ||
     said("climb","ladder"))) {
          print("It looks sturdy enough.  Just push up or down when you're centered on the ladder to climb.");
          }

if ((said("look","statue") ||
     said("push","statue") ||
     said("get","statue"))) {
          print("There are some creepy statues here, and as much as you'd like them out of the way, they are firmly cemented to the floor.");
          }

if (said("look","handle")) {
    print("It's a standard handle.  I wonder what it does.");
    }

if (said("jump")) {
    print("This is a non-jumping game.");
    }

if (said("use","handle")) {
    if (universe<=10) {
        if (bridge_switch) {
            reset(bridge_switch);
            }
        else {
            set(bridge_switch);
            }
        new.room(52);
        }
    else {
        print("Your arms are too short.");
        }
    }

if (ego_edge_code == right_edge) {   // ego touching right edge of screen
  new.room(53);
}

if (ego_edge_code == left_edge) {//ego touching left edge of screen
  new.room(51);
  }

if (sound_flag) {
    sound(22, sound_flag);
    }

call(100);

return();